This blog entry provides an example of inserting a registry value in an MSI database using the Modify method and VBScript.  It follows on from the previous blog post which provided a tutorial on deleting a registry value from an MSI database using the Modify method and VBScript.

It forms part 9 of an 17-part series that explores how to use VBScript to manipulate MSI relational databases using the Windows Installer API.  Throughout this series of tutorials, we identify the common issues that we encounter and the best practises that we use to overcome them.

In this example, we run a SQL statement to include the columns of data which we want to insert – this also helps us to identify if the row of data already exists before we try to insert it!

Note that we MUST include all of the non-nullable columns as a minimum in the SQL statement. When a column is not nullable, it means we MUST specify a value when we insert the record. Otherwise the insertion will fail. To find the non-nullable columns, consult the Windows Installer help file (MSI.chm) or MSDN. For example:

Inserting a registry value in an MSI database (Modify method) 1

The four non-nullable columns which we MUST include when inserting into the Registry table are:

Registry
Root
Key
Component_

Dim sql : sql = "SELECT `Registry`,`Root`,`Key`,`Component_` FROM `Registry` WHERE `Registry` = 'MyNewSampleReg'"

If we were lazy, we could just return all rows using the following:

Dim sql : sql = "SELECT * FROM `Registry` WHERE `Registry` = 'MyNewSampleReg'"

This time when we execute the query, we’re not going to loop through any records using the While…Wend loop. All we want to do is see if the record already exists:

If regRecord Is Nothing Then

and if it doesn’t, we’ll start to create a new record and populate the values….

'There are no records returned, so we create a new record
    Set regRecord = oInstaller.CreateRecord(4)

    'in this example, we've created a record ensuring that all the non-nullable field are populated
    regRecord.StringData(1) = "MyNewSampleReg"
    regRecord.IntegerData(2) = 2
    regRecord.StringData(3) = "SOFTWARE\alkaneTest"
    regRecord.StringData(4) = "alkaneComponent"

Note how we’ve used StringData for columns which can accept strings as their data types, and IntegerData for columns which accept numeric values only.
Again, to find columns with an ‘Integer’ data type you should consult the Windows Installer help file (MSI.chm) or MSDN.

Once we’ve created our new record, we insert it:

regView.Modify msiViewModifyInsert,regRecord

And here is the finished script:

'create 2 constants - one for when we want to just query the MSI (read) and one for when we want to make changes (write)

Const msiOpenDatabaseModeReadOnly = 0
Const msiOpenDatabaseModeTransact = 1

Const msiViewModifyInsert = 1
Const msiViewModifyUpdate = 2
Const msiViewModifyDelete = 6
Const msiViewModifyReplace = 4

'create WindowsInstaller.Installer object
Dim oInstaller : Set oInstaller = CreateObject("WindowsInstaller.Installer")

'open the MSI (the first argument supplied to the vbscript)
Dim oDatabase : Set oDatabase = oInstaller.OpenDatabase(WScript.Arguments(0),msiOpenDatabaseModeTransact) 

Dim sql : sql = "SELECT `Registry`,`Root`,`Key`,`Component_` FROM `Registry` WHERE `Registry` = 'MyNewSampleReg'"
'create a view of the registry we want to see
Dim regView : Set regView = oDatabase.OpenView(sql)

'execute the query
regView.Execute 
Set regRecord = regView.Fetch

If regRecord Is Nothing Then
	'There are no records returned, so we create a new record
	Set regRecord = oInstaller.CreateRecord(4)

	'in this example, we've created a record ensuring that all the non-nullable field are populated
	regRecord.StringData(1) = "MyNewSampleReg"
	regRecord.IntegerData(2) = 2
	regRecord.StringData(3) = "SOFTWARE\alkaneTest"
	regRecord.StringData(4) = "alkaneComponent"

	regView.Modify msiViewModifyInsert,regRecord

End If

oDatabase.Commit

regView.Close
Set regView = Nothing
Set regRecord = Nothing
Set oDatabase = Nothing
Set oInstaller = Nothing

Thanks for reading about inserting a registry value in an MSI database using the Modify method.  Next you can find out how to handle tables that don’t exist in an MSI database using VBScript.

Inserting a registry value in an MSI database (Modify method)

4 thoughts on “Inserting a registry value in an MSI database (Modify method)

  1. Hi,

    i have used your above script to add 1 new Feature if it does not exist in the MSI using the below script.

    when i execute the script it executes without any error but does not create the feature, Please help.

    Many Thanks
    shashi

    Const msiOpenDatabaseModeReadOnly = 0
    Const msiOpenDatabaseModeTransact = 1
    Const Audit = “Audit”
    Const INSTALLDIR = “INSTALLDIR”
    Const msiViewModifyInsert = 1
    Const msiViewModifyUpdate = 2
    Const msiViewModifyDelete = 6
    Const msiViewModifyReplace = 4
    Dim oInstaller : Set oInstaller = CreateObject(“WindowsInstaller.Installer”)
    Dim oDatabase : Set oDatabase = oInstaller.OpenDatabase(WScript.Arguments(0),msiOpenDatabaseModeTransact)

    If oDatabase.TablePersistent(“Feature”) = 1 Then

    ‘create a view of the registry we want to see
    Dim sql : sql = “SELECT `Feature` FROM `Feature`”
    Dim regView : Set regView = oDatabase.OpenView(sql)

    ‘execute the query
    regView.Execute

    ‘fetch the first row of data (if there is one!)
    Dim regRecord : Set regRecord = regView.Fetch

    ‘whilst we’ve returned a row and therefore regRecord is not Nothing
    While Not regRecord Is Nothing

    If regRecord.StringData(1) <> “Audit” Then

    Else
    Dim test : test = “INSERT INTO Feature (`Feature`,`Title`,`Description`,`Display`,`Level`,`Directory_`,`Attributes`) VALUES (‘Audit’,’Audit’,’Audit’,3,1,’INSTALLDIR’,0)”
    Dim tempView : Set tempView = oDatabase.OpenView(test)
    tempView.Execute

    End If
    Set regRecord = regView.Fetch
    Wend
    End If

    oDatabase.Commit

    regView.Close
    Set regView = Nothing
    Set regRecord = Nothing
    Set oDatabase = Nothing
    Set oInstaller = Nothing

Comments have now been disabled. If you have a question to ask about this post please ask the community!